DUzun's Web
Programare, proiecte personale, divertisment

Program P131;

 { Parcurgerea arborelui binar }

type Arbore=^Nod;

     Nod=record

               Info : string;

            Stg, Dr : Arbore

         end;

​

var  T : Arbore;    { rădăcina }

​

function Arb : Arbore;

 { crearea arborelui binar }

var R : Arbore;

    s : string;

begin

 readln(s);

 if s='' then Arb:=nil

    else begin

          new(R);

          R^.Info:=s;

          writeln('Daţi descendentul stîng al nodului ', s, ':');

          R^.Stg:=Arb;

          writeln('Daţi descendentul drept al nodului ', s, ':');

          R^.Dr:=Arb;

          Arb:=R;

         end;

end; { Arb }

​

procedure AfisArb(T : Arbore; nivel : integer);

 { afişarea arborelui binar }

var i : integer;

begin

 if T<>nil then

    begin

     AfisArb(T^.Stg, nivel+1);

     for i:=1 to nivel do write('    '); writeln(T^.Info);

     AfisArb(T^.Dr, nivel+1);

    end;

end; { AfisareArb }

​

procedure Preordine(T : Arbore);

 { traversare RSD }

begin

 if T<>nil then begin

                  writeln(T^.Info);

                  Preordine(T^.Stg);

                  Preordine(T^.Dr)

                end;

end; { Preordine }

​

procedure Inordine(T : Arbore);

 { traversare SRD }

begin

 if T<>nil then begin

                  Inordine(T^.Stg);

                  writeln(T^.Info);

                  Inordine(T^.Dr)

                end;

end; { Inordine }

​

procedure Postordine(T : Arbore);

 { traversare SDR }

begin

 if T<>nil then begin

                  Postordine(T^.Stg);

                  Postordine(T^.Dr);

                  writeln(T^.Info)

                end;

end; { Postordine }

​

begin

 writeln('Daţi rădăcina:');

 T:=Arb;

 AfisArb(T, 0);

 readln;

 writeln('Parcurgere în preordine:');

 Preordine(T);

 readln;

 writeln('Parcurgere în inordine:');

 Inordine(T);

 readln;

 writeln('Parcurgere în postordine:');

 Postordine(T);

 readln;

end.

​

​